Keyestudio MMA8452Q Modül 3 Eksenli Dijital İvme Sensörü

Keyestudio MMA8452Q Modül 3 Eksenli Dijital İvme Sensörü Tanıtım

MMA8452Q, 12 bit çözünürlüğe sahip akıllı düşük güçlü, üç eksenli, kapasitif bir mikro-makine ivme sensörüdür. Bu ivme sensörü esnek, kullanıcı tarafından programlanabilme seçenekleri ve iki kesinti pini yapılandırmasıyla zengin özelliklere sahip yerleşik bir performansa sahiptir. Gömülü kesinti işlevi, genel güç tüketimini koruyabilir ve ana işlemcideki verileri sürekli sorgulama yükünü ortadan kaldırır.
Ayrıca, MMA8452Q, gerçek zamanlı olarak mevcut filtrelenmemiş verilerin yanı sıra, high-pass filtrelenmiş verilerle ±2g / ±4g / ±8g kullanıcı opsiyonlu tam ölçeklere sahiptir.. Bu cihaz, MMA8452Q'nin olayı izlerken statik durumda düşük güç modunu sürdürmesini sağlamak üzere  uyku modu kesme sinyali üretmek üzere gömülü bir işlevi yapılandırabilir.

Parametreler

• Güç Kaynağı Voltajı: 1,95 V ila 3,6 V
• Arayüz Gerilimi ： 1,6 V - 3,6 V
• ± 2g / ± 4g / ± 8g: İsteğe bağlı dinamik aralık
• Çıkış veri hızı (ODR) aralığı ： 1,56 Hz - 800 Hz
• Gürültü: 99μg / √Hz
• 12 bit ve 8 bit dijital çıkışlar
• I2C dijital çıkış arayüzü (çekme direnci 4,7 kΩ olduğunda 2,25 MHz'ye kadar)
• Altı kesinti kaynağına uygulanan iki programlanabilir kesinti pini
• Üç hareket algılama gömülü kanal: serbest düşme algılama, darbe algılama, sallama algılama
• Gecikme telafisi ayarı ile yön (enine / boyuna) algılama
• Otomatik uyarılma ve otomatik uyuyan ODR otomatik olarak değiştirilebilir
• High-Pass filtreleme verileri gerçek zamanlı olarak dışa aktarılabilir
• Güç tüketimi ： 6 μA - 165 μA

Bağlantı Şeması

Örnek Kod

Kütüphanesi İndir: [1]
MMA8452Q Kütüphanesi İndir: [2]

#include  // Must include Wire library for I2C
#include  // Includes the SFE_MMA8452Q library
// Begin using the library by creating an instance of the MMA8452Q
//  class. We'll call it "accel". That's what we'll reference from
//  here on out.
MMA8452Q accel;
// The setup function simply starts serial and initializes the
//  accelerometer.
void setup()
{
  Serial.begin(9600);
  Serial.println("MMA8452Q Test Code!");
  
  // Choose your adventure! There are a few options when it comes
  // to initializing the MMA8452Q:
  //  1. Default init. This will set the accelerometer up
  //     with a full-scale range of +/-2g, and an output data rate
  //     of 800 Hz (fastest).
  accel.init();
  //  2. Initialize with FULL-SCALE setting. You can set the scale
  //     using either SCALE_2G, SCALE_4G, or SCALE_8G as the value.
  //     That'll set the scale to +/-2g, 4g, or 8g respectively.
  //accel.init(SCALE_4G); // Uncomment this out if you'd like
  //  3. Initialize with FULL-SCALE and DATA RATE setting. If you
  //     want control over how fast your accelerometer produces
  //     data use one of the following options in the second param:
  //     ODR_800, ODR_400, ODR_200, ODR_100, ODR_50, ODR_12,
  //     ODR_6, or ODR_1. 
  //     Sets to 800, 400, 200, 100, 50, 12.5, 6.25, or 1.56 Hz.
  //accel.init(SCALE_8G, ODR_6);
}

// The loop function will simply check for new data from the
//  accelerometer and print it out if it's available.
void loop()
{
  // Use the accel.available() function to wait for new data
  //  from the accelerometer.
  if (accel.available())
  {
    // First, use accel.read() to read the new variables:
    accel.read();
    
    // accel.read() will update two sets of variables. 
    // * int's x, y, and z will store the signed 12-bit values 
    //   read out of the accelerometer.
    // * floats cx, cy, and cz will store the calculated 
    //   acceleration from those 12-bit values. These variables 
    //   are in units of g's.
    // Check the two function declarations below for an example
    // of how to use these variables.
    printCalculatedAccels();
    //printAccels(); // Uncomment to print digital readings
    
    // The library also supports the portrait/landscape detection
    //  of the MMA8452Q. Check out this function declaration for
    //  an example of how to use that.
    printOrientation();
    
    Serial.println(); // Print new line every time.
  }
}

// The function demonstrates how to use the accel.x, accel.y and
//  accel.z variables.
// Before using these variables you must call the accel.read()
//  function!
void printAccels()
{
  Serial.print(accel.x, 3);
  Serial.print("\t");
  Serial.print(accel.y, 3);
  Serial.print("\t");
  Serial.print(accel.z, 3);
  Serial.print("\t");
}

// This function demonstrates how to use the accel.cx, accel.cy,
//  and accel.cz variables.
// Before using these variables you must call the accel.read()
//  function!
void printCalculatedAccels()
{ 
  Serial.print(accel.cx, 3);
  Serial.print("\t");
  Serial.print(accel.cy, 3);
  Serial.print("\t");
  Serial.print(accel.cz, 3);
  Serial.print("\t");
}

// This function demonstrates how to use the accel.readPL()
// function, which reads the portrait/landscape status of the
// sensor.
void printOrientation()
{
  // accel.readPL() will return a byte containing information
  // about the orientation of the sensor. It will be either
  // PORTRAIT_U, PORTRAIT_D, LANDSCAPE_R, LANDSCAPE_L, or
  // LOCKOUT.
  byte pl = accel.readPL();
  switch (pl)
  {
  case PORTRAIT_U:
    Serial.print("Portrait Up");
    break;
  case PORTRAIT_D:
    Serial.print("Portrait Down");
    break;
  case LANDSCAPE_R:
    Serial.print("Landscape Right");
    break;
  case LANDSCAPE_L:
    Serial.print("Landscape Left");
    break;
  case LOCKOUT:
    Serial.print("Flat");
    break;
  }
}

Sonuç

Şemadaki gibi kablolamayı ve kod yüklemeyi yaptıktan sonra çalıştırıp, seri monitörü açın ve 3-eksen hızlanma sensörü ve statülerini aşağıdaki grafikteki gibi izleyin.

Dökümanlar

PDF File:
PDF Dosyası

Kütüphaneler indir MMA8452Q:
MMA8452Q Kütüphanesi

VIDEO: